DoEvents应用

使用 DoEvent

基本用法

用法难点

DoEvents应用

DoEvents函数 返回

转让控制权，以便让操作系统处理其它的事件。

语法

DoEvents( )

说明

DoEvents 函数会返回一个 Integer，以代表 Visual Basic 独立版本中打开的窗体数目，例如，Visual Basic 专业版，在其它的应用程序中，DoEvents 返回 0。

DoEvents 会将控制权传给操作系统。当操作系统处理完队列中的事件，并且在 SendKeys 队列中的所有键也都已送出之后，返回控制权。

DoEvents 对于简化诸如允许用户取消一个已启动的过程 — 例如搜寻一个文件 — 特别有用。对于长时间过程，放弃控制权最好使用定时器或通过委派任务给 ActiveX EXE 部件来完成。以后，任务还是完全独立于应用程序，多任务及时间片由操作系统来处理。

注意 确保以 DoEvents 放弃控制权的过程，在第一次 DoEvents 返回之前，不能再次被其他部分的代码调用；否则会产生不可预料的结果。此外，如果其它的应用程序可能会和本过程以不可预知的方式进行交互操作，那么也不要使用 DoEvents，因为此时不能放弃控制权。

使用 DoEvent

尽管 Timer 事件是后台处理的最好工具，对耗时极多的任务，情况更是如此，但是，DoEvents 函数还是提供了一种取消任务的简便方法。例如，下列代码将显示一个 "Process" 按钮，单击这个按钮时，它将变成 "Cancel" 按钮。再次单击按钮又将中断正在执行的任务。

´此按钮标题是 "Process"

Private Sub Command1_Click()

&acute；过程的所有实例都共享静态变量。

Static blnProcessing As Boolean

Dim lngCt As Long

Dim intYieldCt As Integer

Dim dblDummy As Double

&acute；按下按钮时，检测是否在处理

If blnProcessing Then

&acute；如果正在处理，则取消

blnProcessing = False

Else

Command1.Caption = "Cancel"

blnProcessing = True

lngCt = 0

&acute；执行一百万次浮点乘法计算。每一千次后，检测是否要取消。

Do While blnProcessing And (lngCt < 1000000)

For intYieldCt = 1 To 1000

lngCt = lngCt + 1

dblDummy = lngCt * 3.14159

Next intYieldCt

&acute;DoEvents 语句允许其它事件发生，包括第二次按此按钮。

DoEvents

Loop

blnProcessing = False

Command1.Caption = "Process"

MsgBox lngCt & " multiplications were performed"

End If

End Sub

DoEvents 将控制切换到操作环境内核。只要此环境中的所有应用程序都有机会响应待处理事件，应用程序就又恢复控制。这不会使应用程序放弃焦点，但会使后台事件能够得到处理。

这种妥协的结果可能并不总是达到预期目标。例如，下述 Click 事件代码在单击按钮后要一直等候十秒钟，而后才显示一条信息。如果在按钮正在等待期间单击它，则将以相反顺序完成单击操作。

Private Sub Command2_Click()

Static intClick As Integer

Dim intClickNumber As Integer

Dim dblEndTime As Double

&acute；每次单击按钮时

&acute；赋予唯一数值。

intClick = intClick + 1

intClickNumber = intClick

&acute；等待十秒。

dblEndTime = Timer + 10#

Do While dblEndTime > Timer

&acute；不做任何事情，仅仅允许

&acute；其它应用程序处理

&acute；它们的事件。

DoEvents

Loop

MsgBox "Click " & intClickNumber & " is finished"

End Sub

对于通过 DoEvents 放弃控制的事件过程，有时可能希望防止在 DoEvents 返回之前重新调用这一过程。否则将无穷无尽地调用该过程，直到系统资源消耗殆尽。可暂时禁止控件，或象上例一样，使用一个静态的“标志”变量防止此事发生。

在使用全局数据时避免 DoEvents

当一个函数已通过 DoEvents 放弃控制时，可相当安全地再次调用函数。例如，下一过程将检测质数并用 DoEvents 语句周期地启动其它应用程序处理事件：

Function PrimeStatus (TestVal As Long) As Integer

Dim Lim As Integer

PrimeStatus = True

Lim = Sqr(TestVal)

For I = 2 To Lim

If TestVal Mod I = 0 Then

PrimeStatus = False

Exit For

End If

If I Mod 200 = 0 Then DoEvents

Next I

End Function

该代码中每重复 200 次就调用一次 DoEvents 语句。这样一来，当该环境的其余部分对事件作出响应时，只要有必要，PrimeStatus 过程就可继续计算。

考虑在调用 DoEvents 期间发生的事情。在其它窗体和应用程序处理事件时将暂停执行应用程序代码。这些事件之一有可能是一个按钮单击操作，它将再次启动 PrimeStatus 过程。

这将导致重新进入 PrimeStatus 过程的，但是，因为在函数每次出现时，堆栈都为其参数和局部变量分配了空间，所以重入不会引发冲突。当然，如果过多调用 PrimeStatus，则可能出现“溢出堆栈空间”错误。

如果 PrimeStatus 使用或改变模块级变量或全局数据，情况就会完全不同。此时，在 DoEvents 能够返回之前执行 PrimeStatus 的另一个实例，这将导致模块数据或全局数据的值完全不同于它们在调用 DoEvents 之前的值。于是，PrimeStatus 的结果将会难以预料。

基本用法

1.窗体启动时如果要处理的事务太多或者用sleep函数暂停，造成其很久都不能出现时怎么办?

例如代码：

Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)'此句写入模块

Private Sub Form_Load()

Show

'**DoEvents句3

Sleep 5000

End Sub

通常容易想到在sleep前加个show，但还是不能达到预想的效果，窗体虽然出来了，但好象只达到了一半，如果加上第3句，将看到效果大不相同。

2.如果有个很耗时的循环导致程序不响应，怎么办?

例如：

Dim L As Long

For L = 1 To 1000000

'** DoEvents

Next L

如果无'**，在循环过程中程序无法处理事件，对于用户来说是不响应，无法控制的

3.想在循环中看到处理过程?

同样：

Dim L As Long

For L = 1 To 10000

'** DoEvents

Text1.Text=Cstr(l)

Next L

无'** 时将无法看到text1中的变化，而只在循环结束时看到最后结果

4.怎样中止循环?

如果有：

Private Sub Command1_Click()

Dim L As Long

Do

L = L + 1

Debug.Print L'在立即窗口中显示

DoEvents

Loop

End Sub

会发现当关闭窗口后，debug中的数据仍然在变化，说明并没结束

需要如下：

Dim IsExit As Boolean

Private Sub Command1_Click()

Dim L As Long

IsExit = False

Do While DoEvents

If IsExit = True Then Exit Do

L = L + 1

Loop

End Sub

Private Sub Command2_Click()''或者在form_unload模块中等等

IsExit = True

End Sub

其中 isexit是全局变量

<>；有些人喜欢用end语句来结束程序，小程序固然可以，但当太大，或者调用了某些特殊的api函数后可能导致预想不到的错误，如果装载了许多东西在程序结束时不处理将卸载很慢，而且这种做法也极不符合正规软件的要求...总之end语句毛病很多，此不详谈，建议少使用甚至不使用

用法难点

1.为什么还是不能结束?

代码如下：

Dim IsExit As Boolean

Private Sub Command1_Click()

Dim L As Long

IsExit = False

Do

If IsExit = True Then Exit Do '句0

DoEvents '** 句1

Text1.Text = CStr(L) '** 句2

L = L + 1

Loop

End Sub

Private Sub Form_Load()

Static N As Long

N = N + 1

MsgBox N

End SubPrivate Sub Form_Unload(Cancel As Integer)

IsExit = True

End Sub

运行结果：启动时msg显示1，点击command1,text1在变化，此时再点form右上角的小差（关闭窗体），发现vb运行控制上的按扭并没变化，说明程序还在运行.如果编译成程序后运行，按下ctrl+del+alt也可发现它还没结束.

通过读代码，并没发现错误，怎么回事?

关键在于"句2"访问了控件的属性 ：

代码运行路径：当在doevents 时，程序释放控制权，可以接收事件消息，form-unload事件只能从此处产生，假设此时关闭form,unload事件发生，即doevents后就运行unload代码，得到isexit=t，并且form卸载，代码返回到doevents 之后，运行句2.注意现在form 已经卸载了，text1从哪里来呢? 于是form重新装载，代码跳到form_load模块运行，所以在关闭窗体后可以看到msg 显示2，此模块运行完后再继续句2后面的代码，当下次循环遇到 句0时退出循环

另：既然退出了循环，怎么还不能结束?

vb程序规定（其实其他的windows语言一样）：窗体卸载时并不是立即卸载其模块代码，而只先卸载窗体中的控件和一些属性值，程序中最后一个窗体卸载时才完全卸载.

在这个单窗体程序中，form卸载时因为循环的控制无法卸载代码，失去了卸载代码的机会，导致再也不能卸载（因为没卸载代码，所以运行的句2是并不会出错）。

另：既然再次运行了form_load代码，怎么看不见窗体?

因为程序启动时窗体的到显示的消息，而只运行此模块并没有（如果在msgbox n语句前加上show，就可以看到它了）

如何解决?

通过以上分析，应该很简单，把句1 和句2调换一下就可以了，关键：

<；仔细分析代码是如何运行的，避免在form已经卸载了情况下访问控件>

2.用了doevents速度太慢了怎么办?

doevents的代价是速度变慢，但要程序响应又不得不用，其实doevents语句允许任何应用程序执行相关事件，而不仅仅是你自己的程序，所以变得很慢.

可以让它响应本程序事件动作，需要用到api函数GetInputState，它的声明语句为：

Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Public Declare Function GetInputState Lib "user32" () As Long

例如用： If GetInputState() Then DoEvents '来代替doevents可使循环运行更快

3.既要同时响应事件又要控件不变化，怎么办?

例如在一个长的循环中向listview控件中添加记录，无doevents时程序无响应，但有它时控件又闪的厉害

解决办法：

a.不一定每次循环都doevents，可以在适当时间时才用,至少没那么闪

b.应用api函数 ValidateRect 功能是使指定的矩型区域生效，通知Windows不对指定的区域进行重画 另：InvalidateRect 功能相反，同时需要用到函数 GetClientRect 取得指定对象的矩形区域 应用*rect函数指定listview的矩形区不重画，即可避免闪烁（但还是要注意恢复重画，否则看不见了真实效果）

4.控时循环和变速齿轮

请看下面的代码：

Option Explicit

Private Declare Function timeGetTime Lib "winmm.dll" () As Long

Dim IsExit As Boolean

Private Sub Command1_Click()

Dim L As Long

Dim Kt As Long

IsExit = False

Do

Kt = timeGetTime()

'do something

L = L + 1

Text1.Text = L

'DoEvents '句 1

While timeGetTime - Kt < 50 '句 2

'While Abs(timeGetTime - Kt) < 50 '句 3

'While Abs(timeGetTime - Kt) And (Not IsExit) < 50 '句 4

DoEvents '句 5

Wend

'DoEvents '句 6

If IsExit Then Exit Do

Loop

End Sub

Private Sub Form_Unload(Cancel As Integer)

IsExit = True

End Sub

其中可用的代码（除去加"'" 号的代码）就是通常的控时循环代码

运行代码并不会出现错误，但在循环过程，请开启变速齿轮看看

当关闭齿轮时，将发现text1.text停止了，别慌，等一段时间它又会继续（这要看你设定的时间，这里是50毫秒，如果设定的太长text1.text将半天都没变化，这是怎么回事?

变速齿轮在启动时将hook.dll映射到你的程序地址运行，更改了timegettime（）函数获取的时间

如果在句2和句3间插入debug.print timegettime,timegettime-kt 将发现，在关闭齿轮的瞬间后者变成了负值，timegettime变小了，所以才造成需要等很久

如果是编写游戏，而用户开了齿轮，那可就惨了

解决方案：

a.用句3代替句2，这个方法最简便，虽然不符实，但不会出问题，建议使用

b.不要句5，换用句6（这样就能达到效果吗?) 因为齿轮还是从doevents语句运行时才能插的进来，所以只要kt=timegettime 和 timegettime之间没有doevents就不会出错

ab.两种方法都有些小问题，但无大碍，有兴趣者请自己分析

5.程序怎么"死了"?

这只是一些人编写时没注意到的小问题，提醒一下：

同样用上面的代码，如果设定的时间太短，以至在代码运行到句2时已经超时了，句5将不能运行了，当然程序就死了哦，以防万一，加上句1，所以此时也只能用a方案来解决齿轮的问题了

有必要用句4代替句3 吗? 除非你设定的时间太长，人家想关闭你的程序要等上好半天。

在MSND上的内容：在使用全局数据时避免 DoEvents

当一个函数已通过 DoEvents 放弃控制时，可相当安全地再次调用函数。例如，下一过程将检测质数并用 DoEvents 语句周期地启动其它应用程序处理事件：

Function PrimeStatus (TestVal As Long) As Integer

Dim Lim As Integer

PrimeStatus = True

Lim = Sqr(TestVal)

For I = 2 To Lim

If TestVal Mod I = 0 Then

PrimeStatus = False

Exit For

End If

If I Mod 200 = 0 Then DoEvents

Next I

End Function

该代码中每重复 200 次就调用一次 DoEvents 语句。这样一来，当该环境的其余部分对事件作出响应时，只要有必要，PrimeStatus 过程就可继续计算。

考虑在调用 DoEvents 期间发生的事情。在其它窗体和应用程序处理事件时将暂停执行应用程序代码。这些事件之一有可能是一个按钮单击操作，它将再次启动 PrimeStatus 过程。

这将导致重新进入 PrimeStatus 过程的，但是，因为在函数每次出现时，堆栈都为其参数和局部变量分配了空间，所以重入不会引发冲突。当然，如果过多调用 PrimeStatus，则可能出现“溢出堆栈空间”错误。

如果 PrimeStatus 使用或改变模块级变量或全局数据，情况就会完全不同。此时，在 DoEvents 能够返回之前执行 PrimeStatus 的另一个实例，这将导致模块数据或全局数据的值完全不同于它们在调用 DoEvents 之前的值。于是，PrimeStatus 的结果将会难以预料。