语法

说明

示例

用来检验数值或引用类型的九个工作表函数，概括为 IS 类函数。可以检验数值的类型并根据参数取值返回 TRUE 或 FALSE。例如，如果数值为对空白单元格的引用，函数 ISBLANK 返回逻辑值 TRUE，否则返回 FALSE。

语法

ISBLANK(value)

ISERR(value)

ISERROR(value)

ISLOGICAL(value)

ISNA(value)

ISNONTEXT(value)

ISNUMBER(value)

ISREF(value)

ISTEXT(value)

Value 为需要进行检验的数值。分别为：空白（空白单元格）、错误值、逻辑值、文本、数字、引用值或对于以上任意参数的名称引用。函数如果为下面的内容，则返回 TRUE

ISBLANK 值为空白单元格。

ISERR 值为任意错误值（除去 #N/A）。

ISERROR 值为任意错误值（#N/A、#VALUE!、#REF!、#DIV/0!、#NUM!、#NAME? 或 #NULL!）。.

ISLOGICAL 值为逻辑值。

ISNA 值为错误值 #N/A（值不存在）。

ISNONTEXT 值为任意不是文本的项（注意此函数在值为空白单元格时返回 TRUE）。

ISNUMBER 值为数字。

ISREF 值为引用。

ISTEXT 值为文本。

说明

IS 类函数的参数 value 是不可转换的。例如，在其他大多数需要数字的函数中，文本值 "19" 会被转换成数字 19。然而在公式 ISNUMBER("19") 中，"19" 并不由文本值转换成别的类型的值，函数 ISNUMBER 返回 FALSE。

IS 类函数在用公式检验计算结果时十分有用。当它与函数 IF 结合在一起使用时，可以提供一种方法用来在公式中查出错误值（请参阅下面的示例）。

示例

ISLOGICAL(TRUE) 等于 TRUE

ISLOGICAL("TRUE") 等于 FALSE

ISNUMBER(4) 等于 TRUE

假设在有关黄金价格的工作表中 C1:C5 的不同区域分别显示出下面的文本值、数字和错误值："Gold"、"Region1"、#REF!、$330.92、#N/A。

ISBLANK(C1) 等于 FALSE

ISERROR(C3) 等于 TRUE

ISNA(C3) 等于 FALSE

ISNA(C5) 等于 TRUE

ISERR(C5) 等于 FALSE

ISNUMBER(C4) 等于 TRUE（如果 $330.92 作为数字输入而不是作为文本输入）

ISREF(Region1) 等于 TRUE（如果 Region1 定义为区域名）

ISTEXT(C2) 等于 TRUE（如果 Region1 的格式为文本）

在另一个工作表中，假设需要计算 A1:A4 区域的平均值，但不能确定单元格内是否包含数字。如果 A1:A4 不包含任何数字，公式 AVERAGE(A1:A4) 返回错误值 #DIV/0!。为了应付这种情况，可以使用下面的公式来查出潜在的错误值：

IF(ISERROR(AVERAGE(A1:A4)),"No Numbers",AVERAGE(A1:A4))